Определяет свойства и методы для главного окна Visual FoxPro. Вы можете использовать _SCREEN для управления главным окном Visual FoxPro как объектом. Есть две версии синтаксиса. 

_SCREEN.PropertyName [= eValue]

_SCREEN.MethodName

Параметры

PropertyName

Определяет свойство для главного окна Visual FoxPro.
eValue

Определяет значение для свойства.
MethodName

Определяет метод выполнения для главного окна Visual FoxPro.

Замечания

Вы не можете создать процедуры событий для _SCREEN . Однако, Вы можете использовать Функцию BINDEVENT( ) для связывания событий _SCREEN с другими объектными событиями и методами. _SCREEN является системной переменной объектного типа.

В версиях Visual FoxPro 7.0 и позже, свойства Top, Height, Left, Width, и hWnd переменной _SCREEN , применяются только для клиентсокй области Visual FoxPro, которая является областью, где можно отобразить текст. В ранних версиях, до Visual FoxPro 7.0, Top и Left ссылались на все окно приложения Visual FoxPro.

CLEAR WINDOWS или RELEASE WINDOWS увтанавливают свойства ReleaseType для _SCREEN в 1. Закрывая конкретные Окна, операционная система устанавливает ReleaseType в 2. Для подробной информации, см. команды CLEAR и RELEASE WINDOWS .

Обратите внимание:
Значение, возвращенное ReleaseType для _SCREEN может отличаться от значения, возвращенного ReleaseType для форм, потому что это - главное окно Visual FoxPro.

Примеры

Следующий пример демонстрирует использование _SCREEN для настраивания главного окна Visual FoxPro. Следующие строки программы объявляют локальные переменные чтобы сохранить текущие параметры настройки:

Скопировать код 
Local oldScreenLeft
Local oldScreenTop
Local oldScreenHeight
Local oldScreenWidth
Local oldScreenColor

Следующий код сохраняет текущие параметры настройки главного окна Visual FoxPro:

Скопировать код 
WITH _SCREEN
 oldScreenLeft=.Left
 oldScreenTop=.Top
 oldScreenHeight=.Height
 oldScreenWidth=.Width
 oldScreenColor = .Backcolor

Следующий код запрещает перерисовку окна, изменяет цвет фона на серый, изменяет стиль бордюра, устанавливает свойства для кнопок управления окном, делает окно подвижным во время run time, определяет высоту и ширину окна, задает заголовок для окна, и разрешает перерисовку экрана:

Скопировать код 
 .LockScreen=.T.
 .BackColor=rgb(192,192,192)
 .BorderStyle=2
 .Closable=.F.
 .ControlBox=.F.
 .MaxButton=.F.
 .MinButton=.T.
 .Movable=.T.
 .Height=285
 .Width=550
 .Caption="Custom Screen"
 .LockScreen=.F.
ENDWITH
=MESSAGEBOX("Return to normal  ",48,WTITLE())

Следующий код переводит свойства окна в первоначальное оригинальное значение:

Скопировать код 
WITH _SCREEN
 .Left = oldScreenLeft
 .Top = oldScreenTop
 .Height = oldScreenHeight
 .Width  = oldScreenWidth
 .BackColor=oldScreenColor
 .LockScreen=.T.
 .BorderStyle=3
 .Closable=.T.
 .ControlBox=.T.
 .MaxButton=.T.
 .MinButton=.T.
 .Movable=.T.
 .Caption="Microsoft Visual FoxPro"
 .LockScreen=.F.
ENDWITH

См. Также